Internet de les coses amb ESP32 i ESP8266

Llegim la temperatura i la humitat des d'una aplicació d'App Inventor

En aquest exemple farem una aplicació d'App Inventor amb la que llegirem, mitjançant Bluetooth, les dades de temperatura i humitat que el microcontrolador ha obtingut del sensor. Recomanem haver mirat abans l'exemple anterior.

Suposarem que es disposa d'uns coneixements mínims sobre l'entorn App Inventor 2; si no és així, en aquest espai web es pot trobar un tutorial i exemples. Atès que el nostre objectiu és l'ús de Bluetooth per fer aplicacions d'IoT, no ens entretindrem gaire en personalitzar l'aplicació (colors, posició dels elements, etc.). L'aspecte visual de l'aplicació, amb uns mínims coneixements d'App Inventor, és fàcil de modificar.

Farem servir una única característica per enviar les dades que posarem separades amb un espai. El programa per al microcontrolador, que llegeix i envia la temperatura i la humitat cada mig minut, és el següent:

#include <ArduinoBLE.h>
#include "DHT.h"
#define DHTPIN 2
#define DHTTYPE DHT22

const char* devUuid = "0000FFE0-0000-1000-8000-00805F9B34FB";
const char* charUuid = "0000FFE1-0000-1000-8000-00805F9B34FB";
unsigned long temps;    // Variable per guardar el temps que ha passat
DHT dht(DHTPIN, DHTTYPE);
BLEService Serv(devUuid); 
BLEStringCharacteristic Character(charUuid, BLERead | BLEWrite, 512);

void setup() {
  dht.begin();
  Serial.begin(9600);
  while (!Serial);  // Espera que s'activi el canal sèrie
  if (!BLE.begin()) {  // Inicialitza BLE
    Serial.println("BLE ha fallat");
    while (1);
  } else {
    Serial.println("BLE inicialitzat");
  }
  // Dona el nom que serà visible
  BLE.setLocalName("MKR Wi-Fi 1010");
  BLE.setAdvertisedService(Serv);
  // Afegeix la característica
  Serv.addCharacteristic(Character);
  // Activa el servei
  BLE.addService(Serv);
  // Inicialitza el valor per a la característica
  Character.writeValue("a");
  // Fa el dispositiu visible
  BLE.advertise();
  temps = millis();
}

void loop() {
  // Definim l'element que controla la connexió
  BLEDevice central = BLE.central();
  // Si hi ha un element central connectat
  if (central) {
    Serial.print("Connectat a l'element central ");
    // Agafa l'adreça MAC
    Serial.println(central.address());
    // Instruccions que es faran mentre es mantingui la connexió
    while (central.connected()) {
      if ((millis() - temps) > 30000){  // Cada 30 s
        temps = millis();
        float temp = dht.readTemperature();
        float hum = dht.readHumidity();
        String resp = String(temp, 1);  // Un sol decimal
        resp = resp + ' ' + String(hum, 1);  // Un sol decimal
        Serial.println(resp);
        Character.writeValue(resp);
      }
    }
    // Si es desconnecta
    Serial.print(F("Desconnectat a l'element central "));
    Serial.println(central.address());
  }
}

Abans de començar a crear l'aplicació, hem de tenir en compte que les funcions per a BLE de l'App Inventor no estan incorporades directament a l'entorn i, per tant, les haurem d'afegir. Un cop estiguem dins de la pantalla de disposició dels elements de l'App Inventor, picarem sobre Extension (a la part inferior del menú de l'esquerra) i farem clic a Import extension. En la finestra que s'obre, picarem URL i en el requadre escriurem l'adreça de l'extensió

http://iot.App Inventor.mit.edu/assets/resources/edu.mit.App Inventor.ble-20181124.aix

També podem descarregar l'extensió al nostre ordinador i carregar-la des d'allà.

La pantalla de l'aplicació contindrà els següents elements:

La presentació dels elements serà la següent:

El programa és el següent:

A l'hora d'emprar l'aplicació, primer haurem de picar el botó Scan i esperar que ens indiqui que ha trobat dispositius. Llavors picarem el botó Connect i triarem el nostre dispositiu. Un cop connectats, podem fer servir els botons On i Off per encendre i apagar, respectivament, el LED. Amb el botó Llegir podrem veure (a l'espai del seu costat) el darrer valor enviat al LED.

A l'hora de provar el programa del microcontrolador, hem de tenir en compte que aquest no s'iniciarà fins que no obrim el monitor sèrie. Així ens assegurem que no perdem cap informació. Si no ens interessa aquest bloqueig, haurem de suprimir la línia que hem marcat en color.

Podem fer una variant de l'aplicació (el programa del microcontrolador no canviaria) en la que les lectures de temperatura i humitat es vagin actualitzant periòdicament, per exemple cada mig minut, sense necessitat de prémer el polsador. El polsador el podem mantenir per si ens interessa llegir les dades en algun moment concret. A la distribució de components només cal afegir el rellotge.

I la nova versió del programa serà la següent:

Aquesta obra d'Oriol Boix està llicenciada sota una llicència no importada Reconeixement-NoComercial-SenseObraDerivada 3.0.